AWK

简介

AWK 是一种优良的文本处理工具。它不仅是 Linux 中也是任何环境中现有的功能最强大的数据处理引擎之一。这种编程及数据操作语言（其名称得自于它的创始人 Alfred Aho、Peter Weinberger 和 Brian Kernighan 姓氏的首个字母）的最大功能取决于一个人所拥有的知识。AWK 提供了极其强大的功能：可以进行样式装入、流控制、数学运算符、进程控制语句甚至于内置的变量和函数。它具备了一个完整的语言所应具有的几乎所有精美特性。实际上 AWK 的确拥有自己的语言：AWK 程序设计语言，三位创建者已将它正式定义为“样式扫描和处理语言”。它允许您创建简短的程序，这些程序读取输入文件、为数据排序、处理数据、对输入执行计算以及生成报表，还有无数其他的功能。

使用方法

awk ‘{pattern + action}’ {filenames}

尽管操作可能会很复杂，但语法总是这样，其中 pattern 表示 AWK 在数据中查找的内容，而 action 是在找到匹配内容时所执行的一系列命令。花括号（{}）不需要在程序中始终出现，但它们用于根据特定的模式对一系列指令进行分组。pattern 就是要表示的正则表达式，用斜杠括起来。awk 语言的最基本功能是在文件或者字符串中基于指定规则浏览和抽取信息，awk 抽取信息后，才能进行其他文本操作。完整的 awk 脚本通常用来格式化文本文件中的信息。通常，awk 是以文件的一行为处理单位的。awk 每接收文件的一行，然后执行相应的命令，来处理文本。

调用 awk

• 命令行方式

awk [-F field-separator] 'commands' input-file(s)
其中，commands 是真正 awk 命令，[- F 域分隔符]是可选的。input-file(s) 是待处理的文件。
在 awk 中，文件的每一行中，由域分隔符分开的每一项称为一个域。通常，在不指名 - F 域分隔符的情况下，默认的域分隔符是空格。

• shell 脚本方式

将所有的 awk 命令插入一个文件，并使 awk 程序可执行，然后 awk 命令解释器作为脚本的首行，一遍通过键入脚本名称来调用。
相当于 shell 脚本首行的：#!/bin/sh
可以换成：#!/bin/awk

• 将所有的 awk 命令插入一个单独文件，然后调用：

awk -f awk-script-file input-file(s)
其中，- f 选项加载 awk-script-file 中的 awk 脚本，input-file(s)跟上面的是一样的。

入门实例（取出 linux 最近登录的五个用户的用户名）

# 下面是取出最近登录的五个用户的信息

[root@localhost ~]# last -n 5
root     pts/1   192.168.1.100  Tue Feb 10 11:21   still logged in
test     pts/1   192.168.1.100  Tue Feb 10 00:46 - 02:28  (01:41)
root     pts/1   192.168.1.100  Mon Feb  9 11:41 - 18:30  (06:48)
dmtsai   pts/1   192.168.1.100  Mon Feb  9 11:41 - 11:41  (00:00)
root     tty1    120.239.75.53  Fri Sep  5 14:09 - 14:10  (00:01)

# 如果只是显示最近登录的 5 个帐号的用户名

$ last -n 5 | awk  '{print $1}'
root
test
root
dmtsai
root

# awk 工作流程是这样的：读入有 '\n' 换行符分割的一条记录，然后将记录按指定的域分隔符划分域，填充域，$0 则表示所有域,$1 表示第一个域,$n 表示第 n 个域。默认域分隔符是 "空白键" 或 "[tab]键", 所以 $1 表示登录用户，$3 表示登录用户 ip, 以此类推。

入门实例（只显示 /etc/passwd 的账户）

$ cat /etc/passwd | awk  -F ':' '{print $1}'  
root
daemon
bin
sys

# 这种是 awk+action 的示例，每行都会执行 action{print $1}。# - F 指定域分隔符为 ':'。# 如果只是显示 /etc/passwd 的账户和账户对应的 shell, 而账户与 shell 之间以 tab 键分割

$ cat /etc/passwd | awk  -F ':' '{print $1"\t"$7}'
root    /bin/bash
daemon  /bin/sh
bin     /bin/sh
sys     /bin/sh
 

# 如果只是显示 /etc/passwd 的账户和账户对应的 shell, 而账户与 shell 之间以逗号分割, 而且在所有行添加列名 name,shell, 在最后一行添加 "blue,/bin/nosh"。$ cat /etc/passwd |awk  -F ':' 'BEGIN {print"name,shell"}  {print $1","$7} END {print"blue,/bin/nosh"}'
name,shell
root,/bin/bash
daemon,/bin/sh
bin,/bin/sh
sys,/bin/sh
....
blue,/bin/nosh

# awk 工作流程是这样的：先执行 BEGING，然后读取文件，读入有 / n 换行符分割的一条记录，然后将记录按指定的域分隔符划分域，填充域，$0 则表示所有域,$1 表示第一个域,$n 表示第 n 个域, 随后开始执行模式所对应的动作 action。接着开始读入第二条记录······直到所有的记录都读完，最后执行 END 操作。# 搜索 /etc/passwd 有 root 关键字的所有行

$ awk -F: '/root/' /etc/passwd
root:x:0:0:root:/root:/bin/bash

# 这种是 pattern 的使用示例，匹配了 pattern(这里是 root)的行才会执行 action(没有指定 action，默认输出每行的内容)。# 搜索支持正则，例如找 root 开头的: awk -F: '/^root/' /etc/passwd

# 搜索 /etc/passwd 有 root 关键字的所有行，并显示对应的 shell

$ awk -F: '/root/{print $7}' /etc/passwd        
/bin/bash

# 这里指定了 action{print $7}

awk 内置变量

awk 有许多内置变量用来设置环境信息，这些变量可以被改变，下面给出了最常用的一些变量。

$n                 # 当前记录的第 n 个字段，比如 n 为 1 表示第一个字段，n 为 2 表示第二个字段。$0                 # 这个变量包含执行过程中当前行的文本内容。ARGC             # 命令行参数的数目。ARGIND             # 命令行中当前文件的位置（从 0 开始算）。ARGV             # 包含命令行参数的数组。CONVFMT         # 数字转换格式（默认值为 %.6g）。ENVIRON         # 环境变量关联数组。ERRNO             # 最后一个系统错误的描述。FIELDWIDTHS     # 字段宽度列表（用空格键分隔）。FILENAME         # 当前输入文件的名。NR                 # 表示记录数，在执行过程中对应于当前的行号

FNR             # 同 NR，但相对于当前文件。FS                 # 字段分隔符（默认是任何空格）。IGNORECASE         # 如果为真，则进行忽略大小写的匹配。NF                 # 表示字段数，在执行过程中对应于当前的字段数。print $NF 答应一行中最后一个字段

OFMT             # 数字的输出格式（默认值是 %.6g）。OFS             # 输出字段分隔符（默认值是一个空格）。ORS             # 输出记录分隔符（默认值是一个换行符）。RS                 # 记录分隔符（默认是一个换行符）。RSTART             # 由 match 函数所匹配的字符串的第一个位置。RLENGTH         # 由 match 函数所匹配的字符串的长度。SUBSEP             # 数组下标分隔符（默认值是 34）。

此外,$0 变量是指整条记录。$1 表示当前行的第一个域,$2 表示当前行的第二个域,…… 以此类推。

统计 /etc/passwd: 文件名，每行的行号，每行的列数，对应的完整行内容:

$ awk  -F ':'  '{print"filename:"FILENAME",linenumber:"NR",columns:"NF",linecontent:"$0}' /etc/passwd
filename:/etc/passwd,linenumber:1,columns:7,linecontent:root:x:0:0:root:/root:/bin/bash
filename:/etc/passwd,linenumber:2,columns:7,linecontent:daemon:x:1:1:daemon:/usr/sbin:/bin/sh
filename:/etc/passwd,linenumber:3,columns:7,linecontent:bin:x:2:2:bin:/bin:/bin/sh
filename:/etc/passwd,linenumber:4,columns:7,linecontent:sys:x:3:3:sys:/dev:/bin/sh

使用 printf 替代 print, 可以让代码更加简洁，易读

awk -F ':' '{printf("filename:%s,linenumber:%s,columns:%s,linecontent:%s\n",FILENAME,NR,NF,$0)}' /etc/passwd

print 和 printf

awk 中同时提供了 print 和 printf 两种打印输出的函数。其中 print 函数的参数可以是变量、数值或者字符串。字符串必须用双引号引用，参数用逗号分隔。如果没有逗号，参数就串联在一起而无法区分。这里，逗号的作用与输出文件的分隔符的作用是一样的，只是后者是空格而已。printf 函数，其用法和 c 语言中 printf 基本相似, 可以格式化字符串, 输出复杂时，printf 更加好用，代码更易懂。

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

awk 编程

变量和赋值

除了 awk 的内置变量，awk 还可以自定义变量。

下面统计 /etc/passwd 的账户人数

awk '{count++;print $0;} END{print"user count is ", count}' /etc/passwd
root:x:0:0:root:/root:/bin/bash
......
user count is  40

count 是自定义变量。之前的 action{}里都是只有一个 print, 其实 print 只是一个语句，而 action{}可以有多个语句，以; 号隔开。

这里没有初始化 count，虽然默认是 0，但是妥当的做法还是初始化为 0:

awk 'BEGIN {count=0;print"[start]user count is ", count} {count=count+1;print $0;} END{print"[end]user count is ", count}' /etc/passwd
[start]user count is  0
root:x:0:0:root:/root:/bin/bash
...
[end]user count is  40
 

统计某个文件夹下的文件占用的字节数

ls -l |awk 'BEGIN {size=0;} {size=size+$5;} END{print"[end]size is ", size}'
[end]size is  8657198

如果以 M 为单位显示:

ls -l |awk 'BEGIN {size=0;} {size=size+$5;} END{print"[end]size is ", size/1024/1024,"M"}' 
[end]size is  8.25889 M

注意，统计不包括文件夹的子目录。

条件语句

awk 中的条件语句是从 C 语言中借鉴来的，见如下声明方式：

if (expression) {
    statement;
    statement;
    ... ...
}

if (expression) {statement;} else {statement2;}

if (expression) {statement1;} else if (expression1) {statement2;} else {statement3;}
 

统计某个文件夹下的文件占用的字节数, 过滤 4096 大小的文件(一般都是文件夹):

ls -l |awk 'BEGIN {size=0;print"[start]size is ", size} {if($5!=4096){size=size+$5;}} END{print"[end]size is ", size/1024/1024,"M"}' 
[end]size is  8.22339 M

循环语句

awk 中的循环语句同样借鉴于 C 语言，支持 while、do/while、for、break、continue，这些关键字的语义和 C 语言中的语义完全相同。

# for 循环

for(变量 in 数组)  
{语句} 
 
for(变量; 条件; 表达式) 
{语句} 


# while 循环

while(表达式) 
    {语句} 


# do...while 循环

do  
{语句} while(条件) 


# 其他相关语句

break：退出程序循环

continue: 进入下一次循环

next：读取下一个输入行

exit：退出主输入循环，进入 END，若没有 END 或 END 中有 exit 语句，则退出脚本。

数组

因为 awk 中数组的下标可以是数字和字母，数组的下标通常被称为关键字(key)。值和关键字都存储在内部的一张针对 key/value 应用 hash 的表格里。由于 hash 不是顺序存储，因此在显示数组内容时会发现，它们并不是按照你预料的顺序显示出来的。数组和变量一样，都是在使用时自动创建的，awk 也同样会自动判断其存储的是数字还是字符串。一般而言，awk 中的数组用来从记录中收集信息，可以用于计算总和、统计单词以及跟踪模板被匹配的次数等等。

显示 /etc/passwd 的账户

$ awk -F ':' 'BEGIN {count=0;} {name[count] = $1;count++;}; END{for (i = 0; i < NR; i++) print i, name[i]}' /etc/passwd
0 root
1 daemon
2 bin
3 sys
4 sync
5 games
......
 

awk 运算

算术运算：（+，-，*，/，&，！，……，++，--）

所有用作算术运算符进行操作时，操作数自动转为数值，所有非数值都变为 0

赋值运算：（=，+=，-=，*=，/=，%=，……=，**=）

逻辑运算符: (||, &&)

关系运算符：（<, <=, >,>=,!=, ==）

正则运算符：（～，～!）(匹配正则表达式，与不匹配正则表达式)

$ awk 'BEGIN{a="100testa";if(a ~ /^100*/){print"ok";}}'
ok

时间函数

格式	描述
mktime(YYYY MM dd HH MM ss[ DST])	生成时间格式
strftime([format [, timestamp]])	格式化时间输出，将时间戳转为时间字符串 具体格式，见下表.
systime()	得到时间戳, 返回从 1970 年 1 月 1 日开始到当前时间 (不计闰年) 的整秒数

strftime 日期和时间格式说明符 :

格式	描述
%a	星期几的缩写(Sun)
%A	星期几的完整写法(Sunday)
%b	月名的缩写(Oct)
%B	月名的完整写法(October)
%c	本地日期和时间
%d	十进制日期
%D	日期 08/20/99
%e	日期，如果只有一位会补上一个空格
%H	用十进制表示 24 小时格式的小时
%I	用十进制表示 12 小时格式的小时
%j	从 1 月 1 日起一年中的第几天
%m	十进制表示的月份
%M	十进制表示的分钟
%p	12 小时表示法(AM/PM)
%S	十进制表示的秒
%U	十进制表示的一年中的第几个星期(星期天作为一个星期的开始)
%w	十进制表示的星期几(星期天是 0)
%W	十进制表示的一年中的第几个星期(星期一作为一个星期的开始)
%x	重新设置本地日期(08/20/99)
%X	重新设置本地时间(12：00：00)
%y	两位数字表示的年(99)
%Y	当前月份
%Z	时区(PDT)
%%	百分号(%)